group = rootProject.group + '.bukkit'
String rootDependencyDir = rootProject.group + '.dependencies'
String dependencyDir = group + '.dependencies'
version = rootProject.version
archivesBaseName = rootProject.name + '-Bukkit'

dependencies {
    implementation "cloud.commandframework:cloud-paper:${rootProject.cloudVersion}"
    implementation "net.kyori:adventure-api:${rootProject.adventureVersion}"
    implementation "net.kyori:adventure-platform-bukkit:${rootProject.adventurePlatformVersion}"
    implementation ("net.kyori:adventure-text-minimessage:${rootProject.adventureMinimessageVersion}") {
        exclude group: 'net.kyori', module: 'adventure-api'
    }
    implementation "org.bstats:bstats-bukkit:${rootProject.bstatsVersion}"
    implementation project(":Common")
    compileOnly 'com.destroystokyo.paper:paper-api:1.16.5-R0.1-SNAPSHOT'
}

processResources {
    from('src/main/resources') {
        include 'plugin.yml'
        expand(version: project.version)
    }
}

shadowJar {
    relocate 'org.bstats', dependencyDir + '.bstats'
    relocate 'net.kyori.adventure', rootDependencyDir + '.adventure'
    relocate 'net.kyori.examination', rootDependencyDir + '.examination'
    relocate 'net.frankheijden.serverutils.common', dependencyDir + '.su.common'
    relocate 'net.kyori.adventure.text.minimessage', dependencyDir + '.adventure.text.minimessage'
}