plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '5.2.0'
}

group = 'net.frankheijden.serverutils'
String dependencyDir = group + '.dependencies'
version = '2.0.0'

sourceCompatibility = targetCompatibility = JavaVersion.VERSION_1_8

subprojects {
    apply plugin: 'java'
    apply plugin: 'checkstyle'
    apply plugin: 'com.github.johnrengelman.shadow'

    sourceCompatibility = targetCompatibility = JavaVersion.VERSION_1_8

    repositories {
        mavenCentral()
        maven { url 'https://repo.aikar.co/content/groups/aikar/' }
        maven { url 'https://papermc.io/repo/repository/maven-public/' }
    }

    dependencies {
        testCompile 'org.assertj:assertj-core:3.15.0'
        testCompile 'org.junit.jupiter:junit-jupiter-api:5.6.2'
        testCompile 'org.junit.jupiter:junit-jupiter-params:5.6.2'
        testCompile 'org.junit.jupiter:junit-jupiter-engine:5.6.2'
    }

    compileJava {
        options.compilerArgs += ["-parameters"]
        options.fork = true
        options.forkOptions.executable = 'javac'
    }

    test {
        useJUnitPlatform()
    }

    checkstyle {
        toolVersion "8.25"
        configFile = rootProject.file('config/checkstyle/checkstyle.xml')

        ignoreFailures = false
        maxErrors = 0
        maxWarnings = 0
    }

    shadowJar.dependsOn checkstyleMain, checkstyleTest, test
}

repositories {
    mavenCentral()
}

dependencies {
    implementation project(path: ':Common', configuration: 'shadow')
    implementation project(path: ':Bukkit', configuration: 'shadow')
    implementation project(path: ':Bungee', configuration: 'shadow')
}

build.dependsOn shadowJar